Файловая система предназначена для организации хранения данных на жёстких дисках и других носителях, здесь и далее речь пойдёт о ФС EXT3, хотя во многих случаях это можно (частично) перенести и на другие FS, например NTFS или FAT.

Почти весь файл хранится в т.н. инодах (inode), это область на диске фиксированного размера (128 байт). Количество инодов так-же фиксировано и неизменно (оно задаётся при создании ФС). В инодах (так-же они называются файловые дескрипторы) хранятся следующие данные:

Восстановить файлы очень просто! Достаточно воспользоваться программой PhotoRec. Я вот воспользовался, и получил 16 каталогов с 7819ю файлами... А что дальше? Все эти файлы названы как-нибудь вроде f8036016.txt, так-как их имена безвозвратно исчезли. Остались только расширения, которые данная программа устанавливает исходя из содержимого восстановленных файлов (скажем, если в файле только буквы, то PhotoRec называет его как .txt). Анализировать это ручками невозможно, а потому заставим sed для начала рассортировать похожие файлы по каталогам.

Вот такой скриптик, запускается так:

find recup_dir.* -type f | ../ln_ext.sed

#!/bin/sed -rnf

h
s%.*(\.[^./]+)$%X\1%
T
H
s%.*%test -d '&'; echo $?%e
/^1$/{
	# нет такого каталога
	g
	s/.*\n(.*)/mkdir '\1'; echo $?/e
	/^0$/!{
		# невозможно создать каталог
		x
		s/.*/Error 71\n&/p
		q 71
	}
}
/^0$/!{
	# неизвестная ошибка
	x
	s/.*/Error 72\n&/p
	q 72
}
x
s%(.*)\n(.*)%ln -fv '\1' '\2' >/dev/stderr; echo $?%e
/^0$/!{
	# ошибка создания ссылки
	s/.*/Error 73 (code &)/p
	q 73
}

Копирование файлов - не самый лучший подход, слишком много надо места и времени. Переносить файлы так-же не самая лучшая идея, при разборе их страшно удалять. Я создаю жёсткие ссылки, которые очень удобны для этого случая.